Programmieren - alles kontrollieren 4.941 Themen, 20.708 Beiträge

Verfolgung starten Optionen

HD-Grösse auslesen

Paisible / 7 Antworten / Flachansicht Nickles

Hallo


Ich (in Ausbildung) schreibe gerade ein Programm, dass gewisse PC-Daten ausliest.


Ist es möglich, die Harddisk-Grösse aus der Registry auszulesen? Das gleiche gilt für die Grafikkarte (Typ, Anzahl Ram)...


Falls das nicht möglich ist, gibt es noch einen anderen Weg als die Registry?

bei Antwort benachrichtigen
In welchem Programm schreibst du? Plazebo
Ich schreibe das Programm in VB Paisible
Der verfügbare und freie RAM lässt sich bei Delphi übrigens wie folgt ... Plazebo
Zu Visual Basic kann ich nix sagen, sollte ähnlich sein wie Delphi. Aber ... Plazebo
HD-Grösse auslesen UselessUser
Schau auch mal unter http://www.activevb-archiv.net/vb/index.html Ist ... UselessUser
REPI Paisible „HD-Grösse auslesen“
Optionen

Dim Tabulator

Set FSO = CreateObject("Scripting.FileSystemObject")

Tabulator = Chr(9)
NeueZeile = vbCRLF

Const DriveTypeWechselbar = 1
Const DriveTypeFest = 2
Const DriveTypeNetzwerk = 3
Const DriveTypeCDROM = 4
Const DriveTypeRAMLW = 5


Function ZeigeLWTyp(LW)

Dim S

Select Case LW.DriveType
Case DriveTypeWechselbar
S = "Wechselmedium"
Case DriveTypeFest
S = "Festpatte"
Case DriveTypeNetzwerk
S = "Netzwerk"
Case DriveTypeCDROM
S = "CD-ROM"
Case DriveTypeRAMLW
S = "RAM-Laufwerk"
Case Else
S = "Unbekannt"
End Select

ZeigeLWTyp = S

End Function

Function ErzeugeLWInformation(FSO)

Dim LWs
Dim LW
Dim S

Set LWs = FSO.Drives

S = "Anzahl der Laufwerke:" & Tabulator & LWs.Count & NeueZeile & NeueZeile

' Erstellt die erste Zeile des Berichts.
S = S & String(2, Tabulator) & "Laufwerk"
S = S & String(3, Tabulator) & "Datei"
S = S & Tabulator & "Gesamt"
S = S & Tabulator & "Frei"
S = S & Tabulator & "Verfügbar"
S = S & Tabulator & "Seriennummer" & NeueZeile

' Erstellt die zweite Zeile des Berichts.
S = S & "Laufwerkbuchstabe"
S = S & Tabulator & "Pfad"
S = S & Tabulator & "Typ"
S = S & Tabulator & "Bereit?"
S = S & Tabulator & "Name"
S = S & Tabulator & "System"
S = S & Tabulator & "Speicherplatz"
S = S & Tabulator & "Speicherplatz"
S = S & Tabulator & "Speicherplatz"
S = S & Tabulator & "Nummer" & NeueZeile

' Trennlinie.
S = S & String(105, "-") & NeueZeile

For Each LW In LWs

S = S & LW.DriveLetter
S = S & Tabulator & LW.Path
S = S & Tabulator & ZeigeLWTyp(LW)
S = S & Tabulator & LW.IsReady

If LW.IsReady Then
If DriveTypeNetzwerk = LW.DriveType Then
S = S & Tabulator & LW.ShareName
Else
S = S & Tabulator & LW.VolumeName
End If

S = S & Tabulator & LW.FileSystem
S = S & Tabulator & LW.TotalSize
S = S & Tabulator & LW.FreeSpace
S = S & Tabulator & LW.AvailableSpace
S = S & Tabulator & Hex(LW.SerialNumber)

End If

S = S & NeueZeile

Next

ErzeugeLWInformation = S

End Function

MsgBox ErzeugeLWInformation(FSO)



ist ein Test VB-Script zum Thema HD !!

Es empfiehlt sich immer, etwas Linux im Hause zu haben.
bei Antwort benachrichtigen